cmake_minimum_required(VERSION 3.13) 
project(PATS CXX)
set(CMAKE_CXX_STANDARD 17)

option(WITH_UNITTESTS       "build unittests"          ON)
option(WITH_PYTHON_BINDINGS "build python bindings"    ON)
option(WITH_MPFR            "use MPFR backend"        OFF)
option(WITH_QUADMATH        "enable QUADMATH backend" OFF)

if(CMAKE_BUILD_TYPE STREQUAL "Release")
    if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|CLANG")
        set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -march=native -O3 -flto")
    endif()
endif()

# if(CMAKE_BUILD_TYPE STREQUAL "Debug")
#     if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|CLANG")
#         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ")
#     endif()
# endif()



##############################################################################
# Library
##############################################################################
add_library(${PROJECT_NAME} INTERFACE)

target_include_directories(${PROJECT_NAME} INTERFACE
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
        $<INSTALL_INTERFACE:$<INSTALL_PREFIX>/include>)

set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake;${CMAKE_MODULE_PATH}")

##############################################################################
# Dependencies
##############################################################################
find_package(OpenMP REQUIRED)
target_link_libraries(${PROJECT_NAME} INTERFACE OpenMP::OpenMP_CXX)


if(WITH_QUADMATH AND CMAKE_CXX_COMPILER_ID STREQUAL "GNU")

    find_package(Quadmath)
    if(${Quadmath_FOUND}) 
        find_package(Boost REQUIRED) 
        target_link_libraries(${PROJECT_NAME} INTERFACE ${QUADMATH_LIBRARIES} Boost::boost)
        # target_compile_options(${PROJECT_NAME} INTERFACE "-fext-numeric-literals")
        target_compile_definitions(${PROJECT_NAME} INTERFACE "WITH_QUADMATH=1")
    endif()
    
elseif(WITH_MPFR) 

    find_package(Boost REQUIRED) 
    find_package(MPFR REQUIRED)
    target_link_libraries(${PROJECT_NAME} INTERFACE Boost::boost)
    target_link_libraries(${PROJECT_NAME} INTERFACE ${MPFR_LIBRARIES})
    target_compile_definitions(${PROJECT_NAME} INTERFACE "WITH_MPFR=1")

endif()


if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")

    find_package(TBB )
    if (TBB_FOUND AND TBB_VERSION STREQUAL "2020.2") 
        target_compile_definitions(${PROJECT_NAME} INTERFACE "HAS_EXECUTION_POLICIES=1")
        target_link_libraries(${PROJECT_NAME} INTERFACE TBB::tbb)
    endif()

endif()

##############################################################################
# bindings
##############################################################################
if (WITH_PYTHON_BINDINGS)
    
    add_subdirectory(src/bindings/python)

endif()

##############################################################################
# unittests
##############################################################################
# if (WITH_UNITTESTS)
#     enable_testing()
#     add_subdirectory(unittests)
# endif()

##############################################################################
# installation
##############################################################################

install(TARGETS               ${PROJECT_NAME}
        EXPORT                ${PROJECT_NAME}_exports
        INCLUDES  DESTINATION include/${PROJECT_NAME}
)
install(EXPORT      ${PROJECT_NAME}_exports
        FILE        ${PROJECT_NAME}-config.cmake 
        NAMESPACE   ${PROJECT_NAME}::
        DESTINATION share/cmake
)
